%--------------------------------------------------%
% vim: ts=4 sw=4 et ft=mercury
%--------------------------------------------------%
% Copyright (C) 2017-2023 The Mercury team.
% This file is distributed under the terms specified in COPYING.LIB.
%--------------------------------------------------%
%
% File: uint32.m
% Main author: juliensf
% Stability: low.
%
% Predicates and functions for dealing with unsigned 32-bit integer numbers.
%
%--------------------------------------------------%
:- module uint32.
:- interface.
:- import_module pretty_printer.
%--------------------------------------------------%
%
% Conversion from int.
%
% from_int(I, U32):
%
% Convert an int into a uint32.
% Fails if I is not in [0, 2^32 - 1].
%
:- pred from_int(int::in, uint32::out) is semidet.
% det_from_int(I) = U32:
%
% Convert an int into a uint32.
% Throws an exception if I is not in [0, 2^32 - 1].
%
:- func det_from_int(int) = uint32.
% cast_from_int(I) = U32:
%
% Convert an int to a uint32.
% Always succeeds, but will yield a result that is mathematically equal
% to I only if I is in [0, 2^32 - 1].
%
:- func cast_from_int(int) = uint32.
%--------------------------------------------------%
%
% Conversion from uint.
%
% from_uint(U, U32):
%
% Convert a uint into a uint32.
% Fails if U is not in [0, 2^32 - 1].
%
:- pred from_uint(uint::in, uint32::out) is semidet.
% det_from_uint(U) = U32:
%
% Convert a uint into a uint32.
% Throws an exception if U is not in [0, 2^32 - 1].
%
:- func det_from_uint(uint) = uint32.
% cast_from_uint(U) = U32:
%
% Convert a uint to a uint32.
% Always succeeds, but will yield a result that is mathematically equal
% to U only if U is in [0, 2^32 - 1].
%
:- func cast_from_uint(uint) = uint32.
%--------------------------------------------------%
%
% Conversion to int.
%
% cast_to_int(U32) = I:
%
% Convert a uint32 to an int.
% Always succeeds. If ints are 64 bits, I will always be
% mathematically equal to U32. However, if ints are 32 bits,
% then I will be mathematically equal to U32 only if
% U32 is in [0, 2^31 - 1].
%
:- func cast_to_int(uint32) = int.
%--------------------------------------------------%
%
% Conversion to uint.
%
% cast_to_uint(U32) = U:
%
% Convert a uint32 to a uint.
% Always succeeds, and always yields a result that is
% mathematically equal to U32.
%
:- func cast_to_uint(uint32) = uint.
%--------------------------------------------------%
%
% Conversion to/from uint8.
%
% cast_to_uint8(U32) = U8:
%
% Convert a uint32 to a uint8.
% Always succeeds, but will yield a result that is mathematically equal
% to U32 only if U32 is in [0, 2^8 - 1].
%
:- func cast_to_uint8(uint32) = uint8.
% cast_from_uint8(U8) = U32:
%
% Convert a uint8 to a uint32.
% Always succeeds, and yields a result that is mathematically equal
% to U8.
%
:- func cast_from_uint8(uint8) = uint32.
%--------------------------------------------------%
%
% Conversion to/from uint16.
%
% cast_to_uint8(U32) = U16:
%
% Convert a uint32 to a uint16.
% Always succeeds, but will yield a result that is mathematically equal
% to U32 only if U32 is in [0, 2^16 - 1].
%
:- func cast_to_uint16(uint32) = uint16.
% cast_from_uint16(U16) = U32:
%
% Convert a uint16 to a uint32.
% Always succeeds, and yields a result that is mathematically equal
% to U16.
%
:- func cast_from_uint16(uint16) = uint32.
%--------------------------------------------------%
%
% Conversion to/from uint64.
%
% cast_to_uint64(U32) = U64:
%
% Convert a uint32 to a uint64.
% Always succeeds, and always yields a result that is
% mathematically equal to U32.
%
:- func cast_to_uint64(uint32) = uint64.
% cast_from_uint64(U64) = U32:
%
% Convert a uint64 to a uint32.
% Always succeeds, but will yield a result that is mathematically equal
% to I only if I is in [0, 2^32 - 1].
%
:- func cast_from_uint64(uint64) = uint32.
%--------------------------------------------------%
%
% Change of signedness.
%
% cast_from_int32(I32) = U32:
%
% Convert an int32 to a uint32. This will yield a result that is
% mathematically equal to I32 only if I32 is in [0, 2^31 - 1].
%
:- func cast_from_int32(int32) = uint32.
%--------------------------------------------------%
%
% Conversion from byte sequence.
%
% from_bytes_le(Byte0, Byte1, Byte2, Byte3) = U32:
%
% U32 is the uint32 whose bytes are given in little-endian order by the
% arguments from left-to-right (i.e. Byte0 is the least significant byte
% and Byte3 is the most significant byte).
%
:- func from_bytes_le(uint8, uint8, uint8, uint8) = uint32.
% from_bytes_be(Byte0, Byte1, Byte2, Byte3) = U32:
%
% U32 is the uint32 whose bytes are given in big-endian order by the
% arguments in left-to-right order (i.e. Byte0 is the most significant
% byte and Byte3 is the least significant byte).
%
:- func from_bytes_be(uint8, uint8, uint8, uint8) = uint32.
%--------------------------------------------------%
%
% Comparisons and related operations.
%
% Less than.
%
:- pred (uint32::in) < (uint32::in) is semidet.
% Greater than.
%
:- pred (uint32::in) > (uint32::in) is semidet.
% Less than or equal.
%
:- pred (uint32::in) =< (uint32::in) is semidet.
% Greater than or equal.
%
:- pred (uint32::in) >= (uint32::in) is semidet.
% Maximum.
%
:- func max(uint32, uint32) = uint32.
% Minimum.
%
:- func min(uint32, uint32) = uint32.
%--------------------------------------------------%
%
% Arithmetic operations.
%
% Addition.
%
:- func uint32 + uint32 = uint32.
:- mode in + in = uo is det.
:- mode uo + in = in is det.
:- mode in + uo = in is det.
:- func plus(uint32, uint32) = uint32.
% Subtraction.
%
:- func uint32 - uint32 = uint32.
:- mode in - in = uo is det.
:- mode uo - in = in is det.
:- mode in - uo = in is det.
:- func minus(uint32, uint32) = uint32.
% Multiplication.
%
:- func (uint32::in) * (uint32::in) = (uint32::uo) is det.
:- func times(uint32, uint32) = uint32.
% Truncating integer division.
%
% Throws a `domain_error' exception if the right operand is zero.
%
:- func (uint32::in) div (uint32::in) = (uint32::uo) is det.
% Truncating integer division.
%
% Throws a `domain_error' exception if the right operand is zero.
%
:- func (uint32::in) // (uint32::in) = (uint32::uo) is det.
% (/)/2 is a synonym for (//)/2.
%
:- func (uint32::in) / (uint32::in) = (uint32::uo) is det.
% unchecked_quotient(X, Y) is the same as X // Y, but the behaviour
% is undefined if the right operand is zero.
%
:- func unchecked_quotient(uint32::in, uint32::in) = (uint32::uo) is det.
% Modulus.
% X mod Y = X - (X div Y) * Y
%
% Throws a `domain_error' exception if the right operand is zero.
%
:- func (uint32::in) mod (uint32::in) = (uint32::uo) is det.
% Remainder.
% X rem Y = X - (X // Y) * Y.
%
% Throws a `domain_error/` exception if the right operand is zero.
%
:- func (uint32::in) rem (uint32::in) = (uint32::uo) is det.
% unchecked_rem(X, Y) is the same as X rem Y, but the behaviour is
% undefined if the right operand is zero.
%
:- func unchecked_rem(uint32::in, uint32::in) = (uint32::uo) is det.
% even(X) is equivalent to (X mod 2 = 0).
%
:- pred even(uint32::in) is semidet.
% odd(X) is equivalent to (not even(X)), i.e. (X mod 2 = 1).
%
:- pred odd(uint32::in) is semidet.
%--------------------------------------------------%
%
% Shift operations.
%
% Left shift.
% X << Y returns X "left shifted" by Y bits.
% The bit positions vacated by the shift are filled by zeros.
% Throws an exception if Y is not in [0, 32).
%
:- func (uint32::in) << (int::in) = (uint32::uo) is det.
:- func (uint32::in) <<u (uint::in) = (uint32::uo) is det.
% unchecked_left_shift(X, Y) is the same as X << Y except that the
% behaviour is undefined if Y is not in [0, 32).
% It will typically be implemented more efficiently than X << Y.
%
:- func unchecked_left_shift(uint32::in, int::in) = (uint32::uo) is det.
:- func unchecked_left_ushift(uint32::in, uint::in) = (uint32::uo) is det.
% Right shift.
% X >> Y returns X "right shifted" by Y bits.
% The bit positions vacated by the shift are filled by zeros.
% Throws an exception if Y is not in [0, 32).
%
:- func (uint32::in) >> (int::in) = (uint32::uo) is det.
:- func (uint32::in) >>u (uint::in) = (uint32::uo) is det.
% unchecked_right_shift(X, Y) is the same as X >> Y except that the
% behaviour is undefined if Y is not in [0, 32).
% It will typically be implemented more efficiently than X >> Y.
%
:- func unchecked_right_shift(uint32::in, int::in) = (uint32::uo) is det.
:- func unchecked_right_ushift(uint32::in, uint::in) = (uint32::uo) is det.
%--------------------------------------------------%
%
% Logical operations.
%
% Bitwise and.
%
:- func (uint32::in) /\ (uint32::in) = (uint32::uo) is det.
% Bitwise or.
%
:- func (uint32::in) \/ (uint32::in) = (uint32::uo) is det.
% Bitwise exclusive or (xor).
%
:- func xor(uint32, uint32) = uint32.
:- mode xor(in, in) = uo is det.
:- mode xor(in, uo) = in is det.
:- mode xor(uo, in) = in is det.
% Bitwise complement.
%
:- func \ (uint32::in) = (uint32::uo) is det.
%--------------------------------------------------%
%
% Operations on bits and bytes.
%
% num_zeros(U) = N:
%
% N is the number of zeros in the binary representation of U.
%
:- func num_zeros(uint32) = int.
% num_ones(U) = N:
%
% N is the number of ones in the binary representation of U.
%
:- func num_ones(uint32) = int.
% num_leading_zeros(U) = N:
%
% N is the number of leading zeros in the binary representation of U,
% starting at the most significant bit position.
% Note that num_leading_zeros(0u32) = 32.
%
:- func num_leading_zeros(uint32) = int.
% num_trailing_zeros(U) = N:
%
% N is the number of trailing zeros in the binary representation of U,
% starting at the least significant bit position.
% Note that num_trailing_zeros(0u32) = 32.
%
:- func num_trailing_zeros(uint32) = int.
% reverse_bytes(A) = B:
%
% B is the value that results from reversing the bytes in the binary
% representation of A.
%
:- func reverse_bytes(uint32) = uint32.
% reverse_bits(A) = B:
%
% B is the is value that results from reversing the bits in the binary
% representation of A.
%
:- func reverse_bits(uint32) = uint32.
% rotate_left(U, D) = N:
%
% N is the value obtained by rotating the binary representation of U
% left by D bits. Throws an exception if D is not in the range [0, 31].
%
:- func rotate_left(uint32, uint) = uint32.
% unchecked_rotate_left(U, D) = N:
%
% N is the value obtained by rotating the binary representation of U
% left by an amount given by the lowest 5 bits of D.
%
:- func unchecked_rotate_left(uint32, uint) = uint32.
% rotate_right(U, D) = N:
%
% N is the value obtained by rotating the binary representation of U
% right by D bits. Throws an exception if D is not in the range [0, 31].
%
:- func rotate_right(uint32, uint) = uint32.
% unchecked_rotate_left(U, D) = N:
%
% N is the value obtained by rotating the binary representation of U
% right by an amount given by the lowest 5 bits of D.
%
:- func unchecked_rotate_right(uint32, uint) = uint32.
% set_bit(U, I) = N:
% N is the value obtained by setting the I'th bit (the bit worth 2^I) of U
% to one. An exception is thrown if I is not in the range [0, 31].
%
:- func set_bit(uint32, uint) = uint32.
% unchecked_set_bit(U, I) = N:
% As above, but the behaviour is undefined if I is not in the range
% [0, 31].
%
:- func unchecked_set_bit(uint32, uint) = uint32.
% clear_bit(U, I) = N:
% N is the value obtained by setting the I'th bit (the bit worth 2^I) of U
% to zero. An exception is thrown if I is not in the range [0, 31].
%
:- func clear_bit(uint32, uint) = uint32.
% unchecked_clear_bit(U, I) = N:
% As above, but the behaviour is undefined if I is not in the range
% [0, 31].
%
:- func unchecked_clear_bit(uint32, uint) = uint32.
% flip_bit(U, I) = N:
% N is the value obtained by flipping the I'th bit (the bit worth 2^I) of
% U. An exception is thrown if I is not in the range [0, 31].
%
:- func flip_bit(uint32, uint) = uint32.
% unchecked_flip_bit(U, I) = N:
% As above, but the behaviour is undefined if I is not in the range
% [0, 31].
%
:- func unchecked_flip_bit(uint32, uint) = uint32.
% bit_is_set(U, I):
% True iff the I'th bit (the bit worth 2^I) of U is one.
% An exception is thrown if I is not in the range [0, 31].
%
:- pred bit_is_set(uint32::in, uint::in) is semidet.
% unchecked_bit_is_set(U, I):
% As above, but the behaviour is undefined if I is not in the range
% [0, 31].
%
:- pred unchecked_bit_is_set(uint32::in, uint::in) is semidet.
% bit_is_clear(U, I):
% True iff the I'th bit (the bit worth 2^I) of U is zero.
% An exception is thrown if I is not in the range [0, 31].
%
:- pred bit_is_clear(uint32::in, uint::in) is semidet.
% unchecked_bit_is_clear(U, I):
% As above, but the behaviour is undefined if I is not in the range
% [0, 31].
%
:- pred unchecked_bit_is_clear(uint32::in, uint::in) is semidet.
%--------------------------------------------------%
%
% Limits.
%
:- func max_uint32 = uint32.
%--------------------------------------------------%
%
% Prettyprinting.
%
% Convert a uint32 to a pretty_printer.doc for formatting.
%
:- func uint32_to_doc(uint32) = pretty_printer.doc.
:- pragma obsolete(func(uint32_to_doc/1), [pretty_printer.int32_to_doc/1]).
%--------------------------------------------------%
%--------------------------------------------------%